Показать сообщение отдельно
Старый 16.01.2008, 16:05   #18
dmitry_a
Постоялец
 
Пол:Мужской
Регистрация: 11.04.2007
Сообщений: 284
Репутация: 85
По умолчанию Ответ: Включение LAN интерфейса в WinXP

Если известно название сетевого интерфейса, и возможно выполнить скрипт на машине с выключенным сетевым интерфейсом, воспользуйся этим..
Код:
Sub Network(Adapter)
'strNetConn = "Сетевые подключения" ' Network Connections для англ. версии ОС
'strConn = "Подключение по локальной сети" ' имя или часть имени подключения
'strEnable = "&Включить" ' En&able для англ. версии ОС
'strDisable = "&Отключить" ' Disa&ble для англ. версии ОС

strNetConn = "Network Connections"
strConn = Adapter
strEnable = "En&able"
strDisable = "Disa&ble"

Set objShell = CreateObject("Shell.Application")
Set objCP = objShell.Namespace(3) ' Панель управления
For Each elem in objCP.Items
    If elem.Name = strNetConn Then
        ' получение папки "Сетевые подключения"
        Set colNetwork = elem.GetFolder
        Exit For
    End If
Next

Set Conn = Nothing
For Each clsConn in colNetwork.Items
    If Instr(LCase(clsConn.name), LCase(strConn)) Then
        ' получение указанного подключения
        Set Conn = clsConn
        Exit For
    End If
Next
If Conn Is Nothing Then
    WScript.Echo "Network Connection not found"
    WScript.Quit
End If

bEnabled = True
Set objEnable = Nothing
Set objDisable = Nothing
For Each clsVerb in Conn.verbs
    ' если доступен глагол "Enable", подключение отключено
    If clsVerb.Name = strEnable Then
        Set objEnable = clsVerb
        bEnabled = False
    End If
    ' если доступен глагол "Disable", подключение подключено
    If clsVerb.name = strDisable Then
        Set objDisable = clsVerb
    End If
Next
If bEnabled Then
    objDisable.DoIt
    strStatus = "disabled."
Else
    objEnable.DoIt
    strStatus = "enabled."
End If
WScript.Sleep 1000
End Sub
dmitry_a вне форума
 
Ответить с цитированием Вверх
 
Время генерации страницы 0.08131 секунды с 9 запросами