Win2003 server + AD + Terminal

[dmitry_a]

Не советывал бы поднимать сервер терминалов на сервере где крутится GC, это мягко говоря не безопасно... и может повлечь неприятные последствия.

Добавлено через 8 минут

Цитата: Сообщение от proshka мужики памагыте, как в скрите при загрузке юзера прописать если юзер относится к определенной группе то подключать один сетевой диск, если к другой, то другой сетефой диск...???

такой ответ подойдет (VBScript)

 Set objSysInfo = CreateObject("ADSystemInfo")
Set objNetwork = CreateObject("Wscript.Network")

strUserPath = "LDAP://" & objSysInfo.UserName
Set objUser = GetObject(strUserPath)

For Each strGroup in objUser.MemberOf
    strGroupPath = "LDAP://" & strGroup
    Set objGroup = GetObject(strGroupPath)
    strGroupName = objGroup.CN

    Select Case strGroupName
        Case "HR"
            objNetwork.MapNetworkDrive "K:", "\\server1\HR"
        
        Case "Accounting_Tools"
        	objNetwork.MapNetworkDrive "N:", "\\server4\accounting_tools"       
        
    End Select
Next

[LelikOFF]

Цитата: Сообщение от proshka мужики памагыте, как в скрите при загрузке юзера прописать если юзер относится к определенной группе то подключать один сетевой диск, если к другой, то другой сетефой диск...???

Делал такую фигную, если подождешь до завтра - скину.
надо описалово найти к ней - писать заново не охота.

[LelikOFF]

В доменной учетной записи добавляем группы в которые нужны для пользователя.
В самой группе в поле заметки пишем букву диска и сетевой путь к папке через ~ типа ~H:~\\server\FolderH~

а далее используем скрипт для пользователя.

  On Error Resume Next
  Dim WshNetwork, sUser, cInitial, startTime, oDrives
  Dim MyString, MyArray


  sPDC = "Rybinsk"
  strFileNameStat" = \\geg\all\statgina.txt"

  Set WshNetwork = CreateObject("WScript.Network")
  Set WshShell = CreateObject("WScript.Shell")
  Set oDrives = WshNetwork.EnumNetworkDrives

  sUser = WshNetwork.UserName
  startTime = Now

  Do While sUser = ""
    If DateDiff("s", startTime, Now) > 30 Then WScript.Quit
    WScript.Sleep 100
    sUser = WshNetwork.UserName
  Loop

  Set adsRootDSE = GetObject("LDAP://RootDSE")
  strDomainDN = adsRootDSE.Get("defaultNamingContext")

  ' Удаляем имеющиеся диски
  For i = 0 to oDrives.Count - 1 Step 2
    WshNetwork.RemoveNetworkDrive (oDrives.Item(i))
  Next
  
  ' Данные о пользователях
  Set oUserAcct = GetObject("LDAP://CN=" & sUser & ",CN=Users," & strDomainDN)
  Set oGroups = oUserAcct.groups

  FullName = oUserAcct.FullName               'Полное имя пользователя домена
  HomeDirectory = oUserAcct.HomeDirectory     'местоположение домашней папки
  Set oUserAcct = Nothing

  ' делаем диски
  For Each oGrp In oGroups
    If Not IsEmpty(oGrp.info) Then  ' если примечание не пустое то обрабатываем его
      MyArray = Split(oGrp.info, "~", -1, 1)
      WshNetwork.MapNetworkDrive MyArray(1), MyArray(2)
    End If
  Next

  ' Мапируем диск L на домашний каталог - можно на другой
  If Not IsEmpty(HomeDirectory) Then
    WshNetwork.MapNetworkDrive "L:", HomeDirectory
  Else
    WScript.Echo "У вас отсутствует домашний каталог"
  End If

  ' Записываем когда и кто с какой машины залогинился
  Set oFSO = WScript.CreateObject("Scripting.FileSystemObject")
  If (oFSO.FileExists(strFileNameStat)) Then
    Set Report = oFSO.OpenTextFile(strFileNameStat, 8, 0)
  Else
    Set Report = oFSO.CreateTextFile(strFileNameStat, True, False)
    Report.WriteLine "Date;Time;userName;ComputerName"
  End If
  
  StrLine = Mid(Date,1,Len(Date)) + ";" + Mid(Time,1,Len(time)) + ";" + WshNetwork.UserName + ";" + WshNetwork.ComputerName

  Report.WriteLine strLine
  Report.Close

  WScript.Echo "Добрый день " & FullName

[proshka]

dmitry_a,
LelikOFF,
спасибо мужики, попробую.

Добавлено через 2 минуты

Цитата: Сообщение от axlwor контроллер домена отключает кэш на запись

стало работать, но галка пропадает после презагрузке...