Отображение файла в память

[Dr Evil]

Здравствуйте! Возникла следующая проблема

var
  VirFileName: PChar;


procedure Test(FileName: string);
var
  hFile: THandle;
  hFileMap: THandle;
  FileSize: Integer;
begin
  hFile := FileOpen(FileName, fmOpenReadWrite);
  FileSize := GetFileSize(hFile, nil);
  hFileMap := CreateFileMapping(hFile, nil, PAGE_READWRITE, 0, FileSize, nil);
  VirtFileName := MapViewOfFile(hFileMap, FILE_MAP_ALL_ACCESS, 0, 0, FileSize);
end;

procedure ReadSwap;
begin
  ShowMessage(StrPas(VirtFileName));
end;

Цитата: Содержимое файла [test] a= b=

ShowMessage нам выводит вообще какую-то кашу

Подскажите плиз

[pluton]

Dr Evil, было бы неплохо, после каждого вызова апи-функции, вызывать GetLastError() + FormatMessage() для проверки результата выполнения. так и узнаем, в чём проблема

[Steve Bloom]

var
  VirFileName: PChar;
  MapName: string;

procedure Test(FileName: string);
var
  hFile: THandle;
  hFileMap: THandle;
  FileSize: Integer;
begin
  MapName := FileName;
  hFile := FileOpen(FileName, fmOpenReadWrite);
  FileSize := GetFileSize(hFile, nil);
  hFileMap := CreateFileMapping(hFile, nil, PAGE_READWRITE, 0, FileSize, @MapName[1]);
  VirtFileName := MapViewOfFile(hFileMap, FILE_MAP_ALL_ACCESS, 0, 0, FileSize);
end;

[IvanVerenich]

А можно немного по подробней

[Dmitry_Ukr]

А просто ShowMessage(String(VirFileName)) не пойдет?

[nabludatel22]

Попробуй вместо hFile := FileOpen(FileName, fmOpenReadWrite); использовать CreateFile

[nanomyte]

Я всегда делал через CreateFile:

type
  TFileMapBuffer=array[0..0] of byte;
  PFileMapBuffer=^TFileMapBuffer;

  TFileMap=object
    LastError:integer;
    Buffer:PFileMapBuffer;
    FileSize:integer{cardinal};
    FileName:string;
    constructor Create;
    function MapFile(aFileName:string):boolean;
    function MapFileShared(aFileName:string):boolean;
    function MapFileRO(aFileName:string):boolean;
    procedure UnmapFile;
    destructor Destroy;
  end;

{$R-}

constructor TFileMap.Create;
begin
  LastError:=0; Buffer:=nil; FileSize:=0; FileName:='';
end;

function TFileMap.MapFile(aFileName:string):boolean;
var
  hhFile,hFileMap:THandle;
begin
  Result:=False;
  UnmapFile; {if we make map for another file and have already mapped smthg}

  hhFile:=CreateFile(PChar(aFileName),GENERIC_READ or GENERIC_WRITE,
    0,nil,OPEN_EXISTING,FILE_ATTRIBUTE_NORMAL,0);
  if(hhFile=INVALID_HANDLE_VALUE)then begin
    LastError:=GetLastError;
    exit;
  end;

  hFileMap:=CreateFileMapping(hhFile,nil,PAGE_READWRITE,0,0,nil);
  if(hFileMap=0)then begin
    LastError:=GetLastError;
    CloseHandle(hhFile);
    exit;
  end;

  FileSize:=GetFileSize(hhFile,nil);
  Buffer:=MapViewOfFile(hFileMap,FILE_MAP_WRITE,0,0,0);
  if(Buffer=nil)then begin
    LastError:=GetLastError;
    CloseHandle(hFileMap); CloseHandle(hhFile);
    exit;
  end;

  FileName:=aFileName;
  CloseHandle(hFileMap); CloseHandle(hhFile);
  LastError:=GetLastError;
  Result:=True;
end;

function TFileMap.MapFileShared(aFileName:string):boolean;
var
  hhFile,hFileMap:THandle;
begin
  Result:=False;
  UnmapFile; {if we make map for another file and have already mapped smthg}
  
  hhFile:=CreateFile(PChar(aFileName),GENERIC_READ or GENERIC_WRITE,
    FILE_SHARE_READ,nil,OPEN_EXISTING,FILE_ATTRIBUTE_NORMAL,0);
  if(hhFile=INVALID_HANDLE_VALUE)then begin
    LastError:=GetLastError;
    exit;
  end;

  hFileMap:=CreateFileMapping(hhFile,nil,PAGE_READWRITE,0,0,nil);
  if(hFileMap=0)then begin
    LastError:=GetLastError;
    CloseHandle(hhFile);
    exit;
  end;

  FileSize:=GetFileSize(hhFile,nil);
  Buffer:=MapViewOfFile(hFileMap,FILE_MAP_WRITE,0,0,0);
  if(Buffer=nil)then begin
    LastError:=GetLastError;
    CloseHandle(hFileMap); CloseHandle(hhFile);
    exit;
  end;

  FileName:=aFileName;
  CloseHandle(hFileMap); CloseHandle(hhFile);
  LastError:=GetLastError;
  Result:=True;
end;

function TFileMap.MapFileRO(aFileName:string):boolean;
var
  hhFile,hFileMap:THandle;
begin
  Result:=False;
  UnmapFile; {if we make map for another file and have already mapped smthg}
  
  //write('CreateFile...');
  hhFile:=CreateFile(PChar(aFileName),GENERIC_READ,
    FILE_SHARE_READ,nil,OPEN_EXISTING,FILE_ATTRIBUTE_NORMAL or FILE_ATTRIBUTE_READONLY,0);
  if(hhFile=INVALID_HANDLE_VALUE)then begin
    LastError:=GetLastError;
    exit;
  end;
  //writeln('ok');

  //write('CreateFileMapping...');
  hFileMap:=CreateFileMapping(hhFile,nil,PAGE_READONLY,0,0,nil);
  if(hFileMap=0)then begin
    LastError:=GetLastError;
    CloseHandle(hhFile);
    exit;
  end;
  //writeln('ok');

  FileSize:=GetFileSize(hhFile,nil);
  //write('MapViewOfFile...');
  Buffer:=MapViewOfFile(hFileMap,FILE_MAP_READ,0,0,0);
  if(Buffer=nil)then begin
    LastError:=GetLastError;
    CloseHandle(hFileMap); CloseHandle(hhFile);
    exit;
  end;
  //writeln('ok');

  FileName:=aFileName;
  CloseHandle(hFileMap); CloseHandle(hhFile);
  LastError:=GetLastError;
  Result:=True;
end;

procedure TFileMap.UnmapFile;
begin
  if(Buffer<>nil)and(FileName<>'')then begin
    UnmapViewOfFile(Buffer);
    LastError:=GetLastError;
    Buffer:=nil; FileSize:=0; FileName:='';
  end;
end;

destructor TFileMap.Destroy;
begin
  UnmapFile;
end;