Компьютерный форум NoWa.cc
Правила Форума
редакция от 29.01.2013
Портал .::2Baksa.Net::. Трекер BRODIM.COM Фильмы HD Онлайн Форум вебкам моделей
Вернуться   Компьютерный форум NoWa.cc > Операционные системы > Microsoft Windows > Windows 200x Server

Уважаемые пользователи nowa.cc и 2baksa.net. У нас сложилось тяжелое финансовое положение. Мы работаем для вас вот уже более 12 лет
и теперь вынуждены просить о помощи. Окажите посильную поддержку проектам. Мы очень надеемся на вас. Реквизиты для переводов ниже.
Webmoney Webmoney Z826074280762 Webmoney R087294265364 Webmoney U051530505194 Webmoney E804621616710
PayPal E-mail для связи / to Contact E-mail для связи по вопросу помощи / to Contact : E-mail для связи / to Contact
Кошелек для вашей помощи Yandex 410013204813773
Yandex Спасибо за поддержку!

Российский интернет-шлюз: контроль трафика, DLP, антивирус, fail2ban, прокси-сервер, шифрование данных, https-фильтрация. Сертификат ФСТЭК

загрузка...
Ответ
 
Опции темы Language
Старый 11.03.2009, 11:01   #1
Новичок
 
Пол:Мужской
Регистрация: 14.08.2007
Сообщений: 9
Репутация: 1
По умолчанию информация из AD в win2003

Доброго времени суток, коллеги встала такая задача вытащить данные по пользователям из AD и разместить полученное на корпаротивном сайте, а инфа нужна по шаблону (ФИО, E-mail, внутренний телефон, внешний телефон). Поиск по сети ничего не дал Может кто нить помоч в решении данного вопроса?
SpyX7 вне форума
 
Ответить с цитированием Вверх
Надежный китайский посредник Taobao.com


Реклама: такси на микроавтобусесистемный блок hp купитькурсы по вентиляции и кондиционированию москваmunich x gresca wтренировочный костюм мизуно


Старый 11.03.2009, 13:20   #2
dmitry_a
Постоялец
 
Пол:Мужской
Регистрация: 11.04.2007
Сообщений: 284
Репутация: 85
По умолчанию Re: информация из AD в win2003

Какие поля заполнены в АД ? лучше названия через ADSIEdit чтобы дать уже работаспособный скрипт, а не шаблон который еще допиливать и допиливать.
dmitry_a вне форума
 
Ответить с цитированием Вверх
Старый 12.03.2009, 07:32   #3
SpyX7
Новичок
 
Пол:Мужской
Регистрация: 14.08.2007
Сообщений: 9
Репутация: 1
По умолчанию Re: информация из AD в win2003

название полей из ADSIEdit {displayName, mail, otherTelephone, telephoneNumber}
SpyX7 вне форума
 
Ответить с цитированием Вверх
Старый 12.03.2009, 15:33   #4
dmitry_a
Постоялец
 
Пол:Мужской
Регистрация: 11.04.2007
Сообщений: 284
Репутация: 85
По умолчанию Re: информация из AD в win2003

Вот скрипт, в нем требуется поменять домен.

p.s. Если надо будет табличку причесать автоматически, сделать это нетрудно просто надо знать как она должна смотреться.

Код:
strDomainDN = "DC=hq,DC=LOCAL"  

strBase   =  "<LDAP://" & strDomainDN & ">;"

'По кодам UseraccountControl Смотреть. http://support.microsoft.com/kb/305144
strFilter = "(&(objectClass=person)(objectClass=user)(otherTelephone=*)(|(useraccountControl=66048)(useraccountcontrol=512))(!(objectClass=computer)));" 
strAttrs  = "Name,mail,telephoneNumber,otherTelephone;" 'Фильтр
strScope  = "subtree"

Set objExcel = WScript.CreateObject("Excel.Application")
objExcel.Visible = True
objExcel.Workbooks.Add

objExcel.ActiveSheet.Name = "UserName " & Left(strDomainDN,19) & "..."
objExcel.ActiveSheet.Range("A1").Activate
objExcel.ActiveCell.Value = "Имя пользователя"						'колонка № 1
objExcel.ActiveCell.Offset(0,1).Value = "Электронная почта "	'колонка 2
objExcel.ActiveCell.Offset(0,2).Value = "Телефон "	'колонка 3
objExcel.ActiveCell.Offset(0,3).Value = "Моб. Номер "	'колонка 4
objExcel.ActiveCell.Offset(1,0).Activate				'переход на следующую строку.


Set objConn = CreateObject("ADODB.Connection")
objConn.Provider = "ADsDSOObject"
objConn.Open "Active Directory Provider"
Set objRS = objConn.Execute(strBase & strFilter & strAttrs & strScope)
objRS.MoveFirst
i = objRS.Fields.Count
WScript.Echo i

while Not objRS.EOF
  
For Each Field in objRS.fields("otherTelephone").value 'Перебераем OtherTelephone, а вдруг там есть еще какие-либо телеофны помимо одного мобильника
 OtherTelephone = OtherTelephone + Field + " "
 WScript.Echo otherTelephone
Next 

	objExcel.ActiveCell.Value = objRS.Fields(0).Value
	objExcel.ActiveCell.Offset(0,1).Value = objRS.Fields(1).Value
	objExcel.ActiveCell.Offset(0,2).Value = objRS.Fields(2).Value
	objExcel.ActiveCell.Offset(0,3).Value = objRS.Fields(3).Value
	objExcel.ActiveCell.Offset(0,3).Value = OtherTelephone
	objExcel.ActiveCell.Offset(1,0).Activate
    objRS.MoveNext
OtherTelephone = Empty
Wend

Последний раз редактировалось dmitry_a; 12.03.2009 в 16:52.. Причина: поправил скрипт под условие.
dmitry_a вне форума
 
Ответить с цитированием Вверх
Старый 12.03.2009, 16:12   #5
Hopeles
Пользователь
 
Аватар для Hopeles
 
Пол:Мужской
Регистрация: 01.11.2007
Сообщений: 199
Репутация: 92
По умолчанию Re: информация из AD в win2003

SpyX7

Код:
dsget /?
dsquery /?
__________________
Хочешь помочь старику - сделай вместо него. Хочешь помочь новичку - сделай вместе с ним.
Хочешь помочь мастеру - отойди и не мешай.А хочешь помочь дураку - сам дурак!
Hopeles вне форума
 
Ответить с цитированием Вверх
Старый 12.03.2009, 17:48   #6
dmitry_a
Постоялец
 
Пол:Мужской
Регистрация: 11.04.2007
Сообщений: 284
Репутация: 85
По умолчанию Re: информация из AD в win2003

Hopeles, Неплохая идея, но скриптом всеже интереснее, можно сразу страничку сделать для корпаративного сайта.

P.S. мой скрипт еще допиливать надо, до нормального внешнего вида и вывода учеток, в которых нету дополнительных телефонов, а так он вполне корректно отрабатывает для данного условия подходит. Чем я и занялся так как самому подобный инструмент пригодится
dmitry_a вне форума
 
Ответить с цитированием Вверх
Старый 13.03.2009, 06:34   #7
SpyX7
Новичок
 
Пол:Мужской
Регистрация: 14.08.2007
Сообщений: 9
Репутация: 1
По умолчанию Re: информация из AD в win2003

возникла маленькая проблемка, я со скриптами мало дело имел можно написать по подробней как с ним работать и в чем запускать
SpyX7 вне форума
 
Ответить с цитированием Вверх
Старый 13.03.2009, 11:23   #8
dmitry_a
Постоялец
 
Пол:Мужской
Регистрация: 11.04.2007
Сообщений: 284
Репутация: 85
По умолчанию Re: информация из AD в win2003

Код вставь в текстовый файл с расширением .vbs и запусти его.

Даю причесанный вариант, уже с устраненным затруднениями которые у меня возникли с предидущим.

Код:
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'Создаем список активных пользователей из Active directory в 
'таблицу формата Excel
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Option Explicit

Dim objRootDSE, strDNSDomain, strBase
Dim adoCommand, adoConnection, objRS, strFilter, strAttributes, strQuery
Dim objExcel, strName, strPhone, strMail, strOtherphone, arrOtherPhone, strItem

Set objRootDSE = GetObject("LDAP://RootDSE")
strDNSDomain = objRootDSE.Get("defaultNamingContext")

Set adoCommand = CreateObject("ADODB.Command")
Set adoConnection = CreateObject("ADODB.Connection")
adoConnection.Provider = "ADsDSOObject"
adoConnection.Open "Active Directory Provider"
adoCommand.ActiveConnection = adoConnection

'Работаем с Excel
Set objExcel = WScript.CreateObject("Excel.Application")
objExcel.Visible = True
objExcel.Workbooks.Add

objExcel.ActiveSheet.Name = "Users " & Left(strDNSDomain,19) & "..."
objExcel.ActiveSheet.Range("A1").Activate

objExcel.ActiveCell.Value = "Имя пользователя"	
objExcel.ActiveCell.Offset(0,1).Value = "Электронная почта "	
objExcel.ActiveCell.Offset(0,2).Value = "Телефон "	
objExcel.ActiveCell.Offset(0,3).Value = "Моб. Номер "	
objExcel.ActiveCell.Offset(1,0).Activate				'переход на следующую строку.


strBase = "<LDAP://" & strDNSDomain & ">"

' Найти все активные учетные записи.
' По кодам UseraccountControl Смотреть. http://support.microsoft.com/kb/305144
strFilter = "(&(objectCategory=person)(objectClass=user)(|(useraccountControl=66048)(useraccountcontrol=512)))"
strAttributes = "name,mail,telephoneNumber,otherTelephone"


' Формеруем строку запроса.
strQuery = strBase & ";" & strFilter & ";" & strAttributes & ";subtree"

' Выполним запрос.
adoCommand.CommandText = strQuery
adoCommand.Properties("Page Size") = 100
adoCommand.Properties("Timeout") = 307
adoCommand.Properties("Cache Results") = False
Set objRS = adoCommand.Execute


While not objRS.EOF

    strName = objRS.Fields("name").Value
    strMail = objRS.Fields("mail").value
    strPhone = objRS.Fields("telephoneNumber").Value

    arrOtherPhone = objRS.Fields("otherTelephone").Value
    If IsNull(arrOtherPhone) Then
        strOtherPhone = ""
    Else
        strOtherPhone = ""
        For Each strItem In arrOtherPhone
            If (strOtherPhone = "") Then
                strOtherPhone = strItem
            Else
                strOtherPhone = strOtherPhone & " " & strItem
            End If
        Next
    End If
    
    'Заполним поля
    objExcel.ActiveCell.Value = strName
	objExcel.ActiveCell.Offset(0,1).Value = strMail
	objExcel.ActiveCell.Offset(0,2).Value = strPhone
	objExcel.ActiveCell.Offset(0,3).Value = strOtherPhone
	objExcel.ActiveCell.AutoFormat
	objExcel.ActiveCell.Offset(1,0).Activate
    
    objRS.MoveNext
Wend

' Чистим память.
Set objRS = Nothing
Set adoCommand = Nothing
Set adoConnection = Nothing

Последний раз редактировалось dmitry_a; 13.03.2009 в 11:41..
dmitry_a вне форума
 
Ответить с цитированием Вверх
Старый 05.08.2013, 11:59   #9
SpyX7
Новичок
 
Пол:Мужской
Регистрация: 14.08.2007
Сообщений: 9
Репутация: 1
По умолчанию Re: информация из AD в win2003

оживим тему
есть задумка получить тот же список пользователей из АД но чтобы он отображался на http странице, которую мона поставить пользователям как основную страницу в браузере. Меня интересует тока код, если можете поделитесь ссылками, статьями. Я пока ничего не нашел а в http я ни в зуб ногой....
__________________
Я еще не волшебник, я еще только учусь
SpyX7 вне форума
 
Ответить с цитированием Вверх
Старый 14.10.2013, 18:06   #10
Ohrimenko
Новичок
 
Пол:Мужской
Регистрация: 04.05.2011
Сообщений: 5
Репутация: 0
По умолчанию Re: информация из AD в win2003

Можете получить список сотрудников (VB скриптом, или CSVDE), открыть таблицу в Excel, и сохранить как HTML
Ohrimenko вне форума
 
Ответить с цитированием Вверх
Ответ
 Уважаемые пользователи портала 2BakSa.NeT и форума NoWa.cc !

  Рады Вам сообщить, что у нас открылся Torrent трекер >> BRODIM.COM

  Приглашаем вас принять участие в обмене полезной информацией,

  и ждем от вас поддержки в создании новых раздач.

Опции темы

Похожие темы
Тема Автор Раздел Ответов Последнее сообщение
Информация о Dlink DIR-615 foxintel Локальные сети и их комплектующие 2 16.12.2009 16:19
Нужна информация по ECU Yunior2007 Автосервис 3 22.07.2009 23:36
практическая информация veschiy Уголовное право 2 03.02.2008 14:19
Информация - Криптография zaqw81 Компьютерная техника, технология и сети 0 12.05.2007 07:10
ИНФОРМАЦИЯ С МАЙДАНА! subvic Пространство бывшего СССР - современные взаимоотношения 30 02.04.2007 23:30

Ваши права в разделе
Вы не можете создавать новые темы
Вы не можете отвечать в темах
Вы не можете прикреплять вложения
Вы не можете редактировать свои сообщения

BB коды Вкл.
Смайлы Вкл.
[IMG] код Вкл.
HTML код Выкл.

Быстрый переход


Текущее время: 23:07. Часовой пояс GMT +3.


Rambler's Top100
Copyright ©2004 - 2017 2Baksa.Net

Powered by vBulletin® Version 3.8.9
Copyright ©2000 - 2017, vBulletin Solutions, Inc. Перевод: zCarot
Время генерации страницы 0.14688 секунды с 10 запросами